home *** CD-ROM | disk | FTP | other *** search
/ Tech Arsenal 1 / Tech Arsenal (Arsenal Computer).ISO / tek-05 / drivers2.zip / NB.ASM < prev    next >
Assembly Source File  |  1992-01-06  |  20KB  |  855 lines
  1. version equ     4
  2.  
  3.         include defs.asm        ;SEE ENCLOSED COPYRIGHT MESSAGE
  4. NCB_NOWAIT         equ 80h         ;  Command wait flag
  5.  
  6. NCB_RESET          equ 32h         ;  Reset adapter
  7. NCB_CANCEL         equ 35h         ;  Cancel command
  8. NCB_STATUS         equ 33h         ;  Get NETBIOS intf status
  9. NCB_UNLINK         equ 70h         ;  Unlink   (RPL)
  10. NCB_ADDNAME        equ 30h         ;  Add name
  11. NCB_ADDGNAME       equ 36h         ;  Add group name
  12. NCB_DELNAME        equ 31h         ;  Delete name
  13. NCB_FINDNAME       equ 78h         ;  Find name
  14. NCB_CALL           equ 10h         ;  Call
  15. NCB_LISTEN         equ 11h         ;  Listen
  16. NCB_HANGUP         equ 12h         ;  Hang up
  17. NCB_SEND           equ 14h         ;  Send
  18. NCB_CHSEND         equ 17h         ;  Chain send
  19. NCB_RECEIVE        equ 15h         ;  Receive
  20. NCB_RECANY         equ 16h         ;  Receive any
  21. NCB_SESSTATUS      equ 34h         ;  Get session status
  22. NCB_SDATAGRAM      equ 20h         ;  Send datagram
  23. NCB_SBROADCAST     equ 22h         ;  Send broadcast
  24. NCB_RDATAGRAM      equ 21h         ;  Receive datagram
  25. NCB_RBROADCAST     equ 23h         ;  Receive broadcast
  26. NCB_TRACE          equ 79h         ;  Start trace
  27.  
  28. ;
  29. ; Network Control Block structure
  30. ;
  31. ncb             struc
  32. ncb_command     db ?
  33. ncb_retcode     db ?
  34. ncb_lsn         db ?
  35. ncb_num         db ?
  36. ncb_buffer      dd ?
  37. ncb_length      dw ?
  38. ncb_callname    db 16 dup(?)
  39. ncb_name        db 16 dup(?)
  40. ncb_rto         db ?
  41. ncb_sto         db ?
  42. ncb_post        dd ?
  43. ncb_lana_num    db ?
  44. ncb_cmd_cplt    db ?
  45. ncb_reserve     db 14 dup(?)
  46. ncb             ends
  47.  
  48. ;
  49. ; ARP packet structure
  50. ;
  51. arp        struc 
  52. arp_hw        dw ?         ; Hardware address length, bytes 
  53. arp_prot    dw ?         ; Protocol type 
  54. arp_hwalen    db ?         ; hardware address length, bytes 
  55. arp_pralen     db ?         ; Length of protocol address 
  56. arp_opcode      dw ?         ; ARP opcode (request/reply) 
  57. arp_shwaddr    db 6 dup(?)    ; Sender hardware address field 
  58. arp_sprotaddr    dd ?        ; Sender Protocol address field 
  59. arp_thwaddr    db 6 dup(?)    ; Target hardware address field 
  60. arp_tprotaddr    dd ?        ; Target protocol address field 
  61. arp        ends
  62.  
  63. code    segment word public
  64.         assume  cs:code, ds:code
  65. ;***************************************************************
  66. prefix          db "TCPIP"
  67.  
  68.         public  int_no
  69. int_no  db      0,0,0,0
  70. ip_adress       dw      2 dup(0)
  71. rq_size         dw      3
  72. padding         dd      0
  73.  
  74.     public    driver_class, driver_type, driver_name, driver_function, parameter_list
  75. driver_class    db      1,0             ;from the packet spec
  76. driver_type     db      0               ;from the packet spec
  77. driver_name     db      'netbios',0     ;name of the driver.
  78. driver_function    db    2
  79. parameter_list    label    byte
  80.     db    1            ;major rev of packet driver
  81.     db    9            ;minor rev of packet driver
  82.     db    14            ;length of parameter list
  83.     db    EADDR_LEN        ;length of MAC-layer address
  84.     dw    1500            ;MTU, including MAC headers
  85.     dw    MAX_MULTICAST * EADDR_LEN    ;buffer size of multicast addrs
  86.     dw    0            ;(# of back-to-back MTU rcvs) - 1
  87.     dw    0            ;(# of successive xmits) - 1
  88. int_num    dw    0            ;Interrupt # to hook for post-EOI
  89.                     ;processing, 0 == none,
  90.  
  91.     public    rcv_modes
  92. rcv_modes    dw    4        ;number of receive modes in our table.
  93.         dw    0,0,0,rcv_mode_3
  94.  
  95. lana_num        db 0
  96. local_ncb_num   db 0              ; handle returned by add_name
  97.  
  98.  
  99.         public  nbsend, nbrcv1, nbrcv2, rcv_buffer1 ; MAP
  100. nbsend          ncb <>
  101. nbrcv1          ncb <>
  102. nbrcv2          ncb <>
  103.  
  104.  
  105. MAX_DG          equ 1500 
  106. rcv_buffer1     db MAX_DG dup(?)
  107.  
  108.     public    as_send_pkt
  109. ; The Asynchronous Transmit Packet routine.
  110. ; Enter with es:di -> i/o control block, ds:si -> packet, cx = packet length,
  111. ;   interrupts possibly enabled.
  112. ; Exit with nc if ok, or else cy if error, dh set to error number.
  113. ;   es:di and interrupt enable flag preserved on exit.
  114. as_send_pkt:
  115.     ret
  116.  
  117.     public    drop_pkt
  118. ; Drop a packet from the queue.
  119. ; Enter with es:di -> iocb.
  120. drop_pkt:
  121.     assume    ds:nothing
  122.     ret
  123.  
  124.     public    xmit
  125. ; Process a transmit interrupt with the least possible latency to achieve
  126. ;   back-to-back packet transmissions.
  127. ; May only use ax and dx.
  128. xmit:
  129.     assume    ds:nothing
  130.     ret
  131.  
  132.  
  133. ;
  134. ; recv_find() requires a pointer to the Ethernet packet type.  Since
  135. ; the incoming packet does not contain an Ethernet packet type field,
  136. ; memory must be allocated to hold the Ethernet packet type.  Space is
  137. ; required for both IP and ARP types.
  138. ;
  139. ip_type        label    byte
  140.         db    08
  141.         db    00    
  142.  
  143. arp_type    label    byte
  144.         db    08
  145.         db    06    
  146.  
  147. gw_switch    db    00
  148.  
  149.  
  150.         public  send_pkt
  151. send_pkt:
  152.         assume ds: nothing
  153. ;enter with ds:si -> packet, cx = packet length.
  154. ;exit with nc if ok, or else cy if error, dh set to error number.
  155.         push    es
  156.         push    bx
  157.         push    ds
  158.  
  159. ;strip off Ethernet header
  160.     add    si,12
  161.     mov    ax, word ptr ds:[si]
  162.     add    si,2
  163.     sub    cx,14
  164. ;
  165. ; Check packet type.  If an ARP packet then construct an ARP reply
  166. ; packet. Otherwise, process the incoming IP packet.
  167. ;
  168.     cmp    ax,0608h
  169.     jne    noarp
  170.     call    arp_reply
  171.     jmp    send_ok
  172. noarp:
  173.     
  174.         push    cs
  175.         pop     es
  176. ;
  177. ; Set up NCB for a "SEND DATAGRAM" operation
  178. ;
  179.         mov     bx,offset cs:nbsend
  180.  
  181.         mov     cs:[bx].ncb_buffer.offs,si
  182.         mov     ax,ds
  183.         mov     cs:[bx].ncb_buffer.segm,ds
  184.         mov     cs:[bx].ncb_length,cx
  185.  
  186.         push    bx
  187.         lea     di,cs:nbsend.ncb_callname
  188. ;
  189. ; If gateway switch set then contruct NETBIOS name based on the destination
  190. ; IP address in the IP packet. Otherwise, construct the NETBIOS name
  191. ; based on the destination Ethernet address.
  192. ;
  193.     mov    al,gw_switch
  194.     cmp    al,0
  195.     je    use_hw_addr
  196.     mov    bx, word ptr ds:[si+16]
  197.     mov    dx, word ptr ds:[si+18]
  198.     jmp    conv_addr
  199. use_hw_addr:
  200.     mov    bx, word ptr ds:[si-12]
  201.     mov    dx, word ptr ds:[si-10]
  202. conv_addr:
  203.         push    cs
  204.         pop     ds
  205.         call    ip_to_nbname
  206.         pop     bx
  207. ;
  208. ; Pass "Send Datagram" NCB to NETBIOS
  209. ;
  210.         int     5ch
  211. ;
  212. ; If "Send Datagram" operation is unsuccessful then print return code and
  213. ; set carry bit.  Otherwise, clear the carry bit.
  214. ;
  215.         cmp     al,0
  216.         jz      send_ok
  217.         add     ax,32
  218.         call    tty
  219.         mov     al,'S'
  220.         call    tty
  221.         stc
  222.         jmp     send_done
  223. send_ok:
  224.         clc
  225. send_done:
  226.         pop     ds
  227.         pop     bx
  228.         pop     es
  229.         ret
  230. ;
  231. ; Formulate a dummy ARP reply packet.  ds:si points at the incoming
  232. ; IP packet.
  233. ;
  234. arp_reply:
  235. ;
  236. ; Save the registers.  Not sure that we need to but it works and I 
  237. ; don't want to change it right now.
  238. ;
  239.     push    ds
  240.     push    es
  241.     push    si
  242.     push    di
  243.     push    cx
  244. ;
  245. ; Check to see if the ARP request is to find the hardware address
  246. ; of the local host.  If so, then don't formulate a reply packet.
  247. ;
  248.     mov    cx,4
  249.     mov    ax,si
  250.     mov    di,ax
  251.     mov    ax,ds
  252.     mov    es,ax
  253.     add    di,arp_sprotaddr
  254.     add    si,arp_tprotaddr
  255.     repe    cmpsb            ; Compare source and target
  256.                     ; protocol address
  257.     jnz    arp_reply_2
  258.     pop    cx
  259.     pop    di
  260.     pop    si
  261.     pop    es
  262.     pop    ds
  263.     ret
  264. arp_reply_2:
  265. ;
  266. ; Restore registers.
  267. ;
  268.     pop    cx
  269.     pop    di
  270.     pop    si
  271.     push    si
  272.     push    di
  273.     push    cx
  274. ;
  275. ; Restore Ethernet header.
  276. ;
  277.     add    cx,14
  278.     sub    si,14 
  279. ;
  280. ; Ask application layer for a memory buffer in which to store
  281. ; incoming packet.
  282. ;
  283.     push    ds
  284.     push    si            ;save si in case we reject it.
  285.     push    bx
  286.     push    cx
  287.  
  288.     mov    ax,cs
  289.     mov    es,ax
  290.     mov    ds,ax
  291.     mov    di, offset arp_type
  292.     mov    dl,cs:driver_class
  293.     call    recv_find        ;look up our type.
  294.     pop    cx
  295.     pop    bx
  296.     pop    si
  297.     pop    ds
  298.  
  299.     mov    ax,es            ;is this pointer null?
  300.     or    ax,di
  301.     je    arp_reply_1        ;yes - just free the frame.
  302.  
  303.     push    cx
  304.     push    es
  305.     push    di
  306. ;
  307. ; Save si,di for future use.
  308. ;
  309.     mov    bx,si
  310.     mov    dx,di
  311. ;
  312. ; Set up ARP Reply by first copying the ARP Request packet.
  313. ;
  314.     cld
  315.     rep    movsb
  316. ;
  317. ; Skip Ethernet header
  318. ;
  319.     add    bx,14
  320.     add     dx,14
  321. ;
  322. ; Swap target and source protocol addresses from ARP request to ARP 
  323. ; reply packet.
  324. ;
  325.     mov    si,bx
  326.     mov    di,dx    
  327.     mov    cx,4
  328.     add    si,arp_tprotaddr
  329.     add    di,arp_sprotaddr
  330.     rep    movsb
  331.  
  332.     mov    si,bx
  333.     mov    di,dx
  334.     mov    cx,4
  335.     add    si,arp_sprotaddr
  336.     add    di,arp_tprotaddr
  337.     rep    movsb
  338. ;
  339. ; Swap target and source hardware addresses from ARP request to ARP 
  340. ; reply packet.
  341. ;
  342.     mov    si,bx
  343.     mov    di,dx
  344.     mov    cx,6
  345.     add    si,arp_shwaddr
  346.     add    di,arp_thwaddr
  347.     rep    movsb
  348. ;
  349. ; Load source hardware address in ARP reply packet.
  350. ;
  351.     mov    si,bx
  352.     mov    di,dx
  353.     add    di,arp_shwaddr
  354.     mov    es:[di],word ptr 0000h
  355.     add    di,2
  356.     mov    cx,4
  357.     add    si,arp_tprotaddr    ; Set Ethernet address in ARP reply
  358.                     ; to target IP address
  359.     rep    movsb
  360. ;
  361. ; Set opcode to REPLY.
  362. ;
  363.     mov    di,dx
  364.     mov    word ptr es:[di].arp_opcode,0200h
  365. ; 
  366. ; Give ARP reply packet that has been constructed to the application
  367. ; layer.
  368. ;
  369.     pop    si
  370.     pop    ds
  371.     pop    cx
  372.     assume    ds:nothing
  373.  
  374.     call    recv_copy
  375.     assume    ds:code
  376.  
  377. arp_reply_1:
  378.  
  379.     pop    cx
  380.     pop    di
  381.     pop    si
  382.     pop    es
  383.     pop    ds
  384.  
  385.     ret
  386.  
  387.         public  get_address
  388. get_address:
  389. ;get the address of the interface.
  390. ;enter with es:di -> place to get the address, cx = size of address buffer.
  391. ;exit with nc, cx = actual size of address, or cy if buffer not big enough.
  392.  
  393.     push    bx
  394. ;
  395. ; Copy psuedo-Ethernet address into buffer allocated by the application
  396. ; layer.  Set Ethernet address to host IP address.
  397. ;
  398.     mov    es:[di],word ptr 0000h
  399.         mov     bx,cs:ip_adress
  400.     mov    es:[di+2],bx
  401.     mov    bx,cs:ip_adress+2
  402.     mov    es:[di+4],bx
  403. ;
  404. ; Set size of psuedo-Ethernet address to be returned.
  405. ;
  406.     mov    cx,6
  407.     pop    bx
  408.     clc
  409.         ret
  410.  
  411.  
  412.     public    set_address
  413. set_address:
  414. ;enter with ds:si -> Ethernet address, CX = length of address.
  415. ;exit with nc if okay, or cy, dh=error if any errors.
  416.     assume    ds:nothing
  417.     ret
  418.  
  419.  
  420. rcv_mode_3:
  421. ;receive mode 3 is the only one we support, so we don't have to do anything.
  422.     ret
  423.  
  424.  
  425.     public    set_multicast_list
  426. set_multicast_list:
  427. ;enter with ds:si ->list of multicast addresses, cx = number of addresses.
  428. ;return nc if we set all of them, or cy,dh=error if we didn't.
  429.     mov    dh,NO_MULTICAST
  430.     stc
  431.     ret
  432.  
  433.  
  434.     public    terminate
  435. terminate:
  436.     ret
  437.  
  438.         public  reset_interface
  439. reset_interface:
  440. ;reset the interface.
  441.         ret
  442.  
  443.  
  444. ;called when we want to determine what to do with a received packet.
  445. ;enter with cx = packet length, es:di -> packet type.
  446.         extrn   recv_find: near
  447.  
  448. ;called after we have copied the packet into the buffer.
  449. ;enter with ds:si ->the packet, cx = length of the packet.
  450.         extrn   recv_copy: near
  451.  
  452.         extrn   count_in_err: near
  453.         extrn   count_out_err: near
  454.         extrn   dwordout: near
  455.         extrn   error: near
  456.  
  457.         public  recv
  458. recv:
  459. ;called from the recv isr.  All registers have been saved, and ds=cs.
  460. ;Upon exit, the interrupt will be acknowledged.
  461.         assume  ds:code
  462.         ret
  463.  
  464.         public nbint  ; MAP
  465. nbint   proc far
  466.         push ds
  467. ;
  468. ; Set data segment to code segment so that we can reference local
  469. ; variables.
  470. ;
  471.         push cs
  472.         pop  ds
  473. ;
  474. ; Retrieve size of received packet
  475. ;
  476.         mov  cx,[bx].ncb_length
  477. ;
  478. ; Check return code.  If there was an error then don't process the
  479. ; packet any further.
  480. ;
  481.         mov  al,[bx].ncb_retcode
  482.         cmp  al,0               ; ok
  483.         jnz  bad_nbint
  484. ;
  485. ; Add Ethernet header.  As well, ensure that minimum packet size is 60
  486. ; bytes; some application packages actually check for minimum packet size.
  487. ;
  488.     add    cx,14 
  489.     cmp    cx,60
  490.     jge    recv_next
  491.     mov    cx,60
  492. recv_next:
  493.     push    si            ;save si in case we reject it.
  494.     push    bx
  495.     push    cx
  496.  
  497.     push    cs
  498.     pop    es
  499.     mov    di, offset ip_type
  500.     mov    dl,cs:driver_class
  501.     call    recv_find        ;look up our type.
  502.  
  503.     pop    cx
  504.     pop    bx
  505.     pop    si
  506.     mov    ax,es            ;is this pointer null?
  507.     or    ax,di
  508.  
  509.     jne  nb_next 
  510.         jmp  skip_copy 
  511. nb_next:
  512.     push bx
  513.     push cx
  514.     push es
  515.     push di
  516. ;
  517. ; Fix up the Ethernet header added to the incoming packet.
  518. ;
  519.     call    fix_header
  520. ;
  521. ; Copy the received packet into buffer allocated by the application
  522. ; software.
  523. ;
  524.     sub    cx,14
  525.         mov     si,[bx].ncb_buffer.offs
  526.     cld
  527.         rep     movsb
  528.     pop si
  529.     pop ds
  530.     pop cx
  531.     assume ds:nothing
  532.         call    recv_copy
  533.     push cs
  534.     pop ds
  535.     assume ds:code
  536.     pop bx
  537. skip_copy:
  538.         mov     [bx].ncb_length,MAX_DG  ; reestablish dg-length
  539. ;
  540. ; Set up to receive another packet.  Construct "receive datagram"
  541. ; NCB.
  542. ;
  543.         push    ds
  544.         pop     es
  545.         int    5ch
  546. ;
  547. ; Check return code.  Print error indication if NETBIOS does not
  548. ; accept NCB.
  549. ;
  550.         mov    al,[bx].ncb_retcode   ; JS added return code
  551.         cmp     al,0ffh
  552.         jz      nbint_pending_ok1
  553.         mov     al,'?'
  554.         call    tty
  555.         add     ax,32
  556.         call    tty
  557.         mov     al,'.'
  558.         call    tty
  559.  
  560. nbint_pending_ok1:
  561.         jmp     short nbint_done
  562.  
  563. bad_nbint:
  564.         add     ax,32
  565.         call    tty
  566.         mov     al,'R'
  567.         call    tty
  568.     jmp    skip_copy
  569.  
  570. nbint_done:
  571.         pop ds
  572.         iret
  573. nbint   endp
  574.  
  575. ;
  576. ; Set destination and source addressess and packet type in an
  577. ; Ethernet header.
  578. ;
  579. fix_header:
  580. ;
  581. ; Set destination address.
  582. ;
  583.     push    cx
  584.     mov    ax,0000h
  585.     stosw
  586.     mov    ax,0c3c4h
  587.     stosw
  588.     mov    ax,0c2cch
  589.     stosw
  590. ;
  591. ; Set source address.  NCB callname contains the string "TCPIP" +
  592. ; source host IP address.  Extract host IP address and copy into
  593. ; Ethernet header as the source address.
  594. ;
  595.     mov    ax,0000h
  596.     stosw
  597.     mov    ax,word ptr [bx].ncb_callname+5
  598.     stosw
  599.     mov    ax,word ptr [bx].ncb_callname+7
  600.     stosw
  601. ;
  602. ; Set packet type to IP.
  603. ;
  604.     mov    ax, 0008h
  605.     stosw    
  606.  
  607.     pop    cx
  608.     ret
  609.  
  610.  
  611.  
  612.         public  nb_stop
  613. nb_stop:
  614.         ;                   unregister name
  615.         push    cs
  616.         pop     es
  617.         lea      bx,nbrcv1
  618.         mov     [bx].ncb_command,NCB_DELNAME
  619. ;        mov     al,lana_num
  620. ;        mov     [bx].ncb_lana_num,al
  621.         int     5ch
  622.         cmp     al,0
  623.         jz      good_delete
  624.         add     ax,32
  625.         call    tty
  626.         mov     al,'I'
  627.         call    tty
  628. good_delete:
  629.         ret
  630.  
  631.  
  632.     public tty
  633. tty:
  634.         push    bx
  635.         mov     ah,14
  636.         int     10h
  637.         pop     bx
  638.         ret
  639.  
  640. ip_to_nbname:
  641.         ;      call with es:di = *ncb_name
  642.         ;            bx and dx = ip_address
  643.  
  644.         mov     cx,5
  645.         mov     si,offset prefix
  646.         rep     movsb
  647.  
  648.         mov     [di],bx
  649.         mov     [di+2],dx
  650.         ret
  651.  
  652.     public    recv_exiting
  653. recv_exiting:
  654. ;called from the recv isr after interrupts have been acknowledged.
  655. ;Only ds and ax have been saved.
  656.     assume    ds:nothing
  657.     ret
  658.  
  659.  
  660. ;any code after this will not be kept after initialization.
  661.         public end_resident ; MAP
  662. end_resident    label   byte
  663.  
  664.  
  665.         public  usage_msg
  666. usage_msg       db      "usage: nb <packet_int_no> <ip.ad.dr.ess> [receive queue size]",CR,LF,'$'
  667.  
  668.         public  copyright_msg
  669. copyright_msg   db      "Packet driver for a netbios device, version ",'0'+version,CR,LF,'$'
  670.                 db      "Portions Copyright 1990, Michael Haberler",CR,LF,'$'
  671.  
  672. ip_adress_name  db      "IP Adress ",'$'
  673. rq_size_name    db      "Receive Queue ",'$'
  674. bad_name_msg    db      " bad returncode from nb add_name",CR,LF,'$'
  675. bad_rcv_msg     db      " bad returncode from nb receive dg",CR,LF,'$'
  676. good_name_msg   db      " good returncode from nb add_name",CR,LF,'$'
  677. good_rcv_msg    db      " good returncode from nb receive dg",CR,LF,'$'
  678. temp_dw         dw      ?
  679.         extrn   set_recv_isr: near
  680.  
  681. ;enter with si -> argument string, di -> word to store.
  682. ;if there is no number, don't change the number.
  683.         extrn   get_number: near
  684.     extrn    skip_blanks: near
  685.  
  686.         public  parse_args
  687. parse_args:
  688. ;exit with nc if all went well, cy otherwise.
  689.     call    skip_blanks
  690.     cmp    al,'-'            ;did they specify a switch?
  691.     jne    not_switch
  692.     cmp    byte ptr [si+1],'g'    ;did they specify '-g'?
  693.     je    got_gw_switch
  694.     stc                ;no, must be an error.
  695.     ret
  696. got_gw_switch:
  697.     mov    gw_switch,1
  698.     add    si,2            ;skip past the switch's characters.
  699.     jmp    parse_args        ;go parse more arguments.
  700. not_switch:
  701.  
  702.         mov     di, offset temp_dw
  703.         mov     bx, offset ip_adress_name
  704.         call    get_number
  705.         mov     ax,temp_dw
  706.         mov     byte ptr ip_adress+0,al
  707.         inc     si
  708.         mov     di, offset temp_dw
  709.         mov     bx, offset ip_adress_name
  710.         call    get_number
  711.         mov     ax,temp_dw
  712.         mov     byte ptr ip_adress+1,al
  713.         inc     si
  714.         mov     di, offset temp_dw
  715.         mov     bx, offset ip_adress_name
  716.         call    get_number
  717.         mov     ax,temp_dw
  718.         mov     byte ptr ip_adress+2,al
  719.         inc     si
  720.         mov     di, offset temp_dw
  721.         mov     bx, offset ip_adress_name
  722.         call    get_number
  723.         mov     ax,temp_dw
  724.         mov     byte ptr ip_adress+3,al
  725.  
  726.         ret
  727.  
  728.  
  729.  
  730.         public  etopen
  731. etopen:
  732.         pushf
  733.         cld
  734.  
  735. ;if all is okay,
  736. ;        mov     bx,offset nbsend
  737.         lea     bx,nbsend
  738.         mov     [bx].ncb_command,NCB_ADDNAME
  739.         mov     al,lana_num
  740.         mov     [bx].ncb_lana_num,al
  741.  
  742.         push    ds
  743.         push    cs
  744.         push    cs
  745.         pop     ds
  746.         pop     es
  747.  
  748.         push    bx
  749.         lea     di,nbsend.ncb_name
  750.         mov     bx,ip_adress
  751.         mov     dx,ip_adress+2
  752.         call    ip_to_nbname
  753.         pop     bx
  754.  
  755. ;    mov    di, offset nbsend.ncb_name
  756. ;    mov    cx,16
  757. ;mike:
  758. ;    mov    al, [di]
  759. ;    call    tty
  760. ;    inc    di
  761. ;    dec    cx
  762. ;    jnz    mike
  763.  
  764.  
  765.         mov     cx,16
  766.         mov     di,offset nbrcv1.ncb_name
  767.         mov     si,offset nbsend.ncb_name
  768.         rep     movsb
  769.         mov     cx,16
  770.         mov     di,offset nbrcv2.ncb_name
  771.         mov     si,offset nbsend.ncb_name
  772.         rep     movsb
  773.  
  774.         int     5ch     ; add_name, -> returns rc in al
  775.         cmp     al,0
  776.         jz      good_name
  777.         mov     dx,0
  778.         mov     ah,0
  779.         call    dwordout
  780.         mov     dx,offset bad_name_msg
  781.         pop     ds
  782.         jmp     error
  783.  
  784. good_name:
  785. ;        mov     dx,offset good_name_msg
  786. ;        call    say
  787.  
  788.         mov     al,[bx].ncb_num
  789.         mov     local_ncb_num,al
  790.         mov     [bx].ncb_command,NCB_SDATAGRAM  ;set send command code
  791.  
  792.         ;       start receive operations
  793. ;        mov     bx,offset nbrcv1
  794.         lea     bx,nbrcv1
  795.         mov     al,NCB_RDATAGRAM+NCB_NOWAIT  ;set rcv command
  796.         mov     [bx].ncb_command,al
  797.  
  798.         mov     al,local_ncb_num
  799.         mov     [bx].ncb_num,al
  800.  
  801.         mov     ax,MAX_DG
  802.         mov     [bx].ncb_length,ax
  803.  
  804.         mov     ax,ds
  805.         mov     [bx].ncb_buffer.segm,ax
  806.         mov     [bx].ncb_buffer.offs,offset rcv_buffer1
  807.  
  808.         mov     [bx].ncb_post.segm,ax
  809.         mov     [bx].ncb_post.offs,offset nbint
  810.  
  811.         mov     al,lana_num
  812.         mov     [bx].ncb_lana_num,al
  813.         int     5ch
  814.  
  815.         cmp     al,0ffh
  816.         jz      pending_ok1
  817.         cmp     al,00h
  818.         jnz     bad_init
  819.  
  820. pending_ok1:
  821.         mov     dx,offset good_rcv_msg
  822.         call    say
  823.  
  824.         mov     dx,offset end_resident
  825.         pop     ds
  826.         popf
  827.         clc
  828.         ret
  829. ;if we got an error,
  830. bad_init:
  831.         mov     ah,0
  832.         mov     dx,0
  833.         call    dwordout
  834.         mov     dx,offset bad_rcv_msg
  835.         call    say
  836.         call    nb_stop
  837.         pop     ds
  838.         popf
  839.         stc
  840.         ret
  841.  
  842.     public    print_parameters
  843. print_parameters:
  844.     ret
  845.  
  846. say:
  847.         mov     ah,9
  848.         int     21h
  849.         ret
  850.  
  851.  
  852. code    ends
  853.  
  854.     end
  855.